Assembly: stack frame analysis of complete function flow

Stack frame (Stack Frame Layout)： The specific process of function call , Is a function execution environment , It includes parameters 、 local variable 、 Return address and other information .

1、 Assembly code of the complete function call process

assume cs:code, ds:data, ss:stack

; -------  Stack segment  -------
stack segment
    db 100 dup(0)
stack ends  

; -------  Data segment  -------
data segment  
    db 100 dup(0) 
data ends

; -------  Code segment  -------
code segment
start:
    ; -------  Manual settings ds、ss Value 
    mov ax, data
    mov ds, ax
    mov ax, stack
    mov ss, ax 
    
    mov si, 1
    mov di, 2
    mov bx, 3 
    mov bp, 4
    
    ; -------  Business logic 
    push 1
    push 2 
    call sum 
    add sp, 4 ;  Stack elimination 
    
    ; -------  sign out 
    mov ax, 4c00h
    int 21h 

; -------  function   
;  Return value ax register 
;  Pass on 2 Parameters ( Put in stack )    
sum:
    ;  Protect bp    
    push bp
    ;  preservation sp Previous value ： Point to bp Previous value 
    mov bp, sp
    ;  reserve 10 Bytes of space for local variables  
    sub sp, 10
    
    ;  Protect registers that may be used 
    push si
    push di
    push bx 
    
    ;  Fill the local variable space int 3（CCCC）： Breakpoint interrupt instruction 
    ; stosw The role of ： take ax Copy the value of to es:di in , meanwhile di It's worth it +2
    mov ax, 0cccch
    ;  Give Way es be equal to ss
    mov bx, ss
    mov es, bx 
    ;  Give Way di be equal to bp-10（ The area with the smallest local variable address ）
    mov di, bp
    sub di, 10   
    ; cx To determine the stosw Number of executions 
    mov cx, 5  
    rep stosw  
    ; rep The role of ： Repeat an instruction （ The number of executions is determined by cx decision ）
     
    ; --------  Business logic  - begin
    ;  Definition 2 Local variables 
    mov word ptr ss:[bp-2], 3 
    mov word ptr ss:[bp-4], 4 
    mov ax, ss:[bp-2]
    add ax, ss:[bp-4]
    mov ss:[bp-6], ax 
    
    ;  Accessing parameters in the stack 
    mov ax, ss:[bp+4]
    add ax, ss:[bp+6] 
    add ax, ss:[bp-6]   
    ; --------  Business logic  - end 
    
    ;  Recover the value of the register 
    pop bx
    pop di
    pop si
                       
    ;  recovery sp
    mov sp, bp
    ;  recovery bp
    pop bp
    
    ret 
                
code ends  

end start

2、 Document description of the complete function call process

1、push Parameters
2、push The return address of the function
3、push bp （ Retain bp Previous value , Convenient for later recovery ）
4、mov bp, sp （ Retain sp Previous value , Convenient for later recovery ）
5、sub sp, The size （ Allocate space to local variables ）
6、 Protect possible registers
7、 Use CC（int 3） Fill the space of local variables

8.-------- Execute business logic --------

9、 Restore the value before the register
10、mov sp, bp （ recovery sp Previous value ）
11、pop bp （ recovery bp Previous value ）
12、ret （ Take the return address of the function out of the stack , Execute the next command ）
13、 Restore stack balance （add sp, Space occupied by parameters ）

3、 The function completely calls the gif chart

4、 Enter the sub function stack frame to execute the logic

5、 The subfunction is released from the processing logic