Ardunio esp32 obtains real-time temperature and humidity in mqtt protocol (DH11)

esp32 stay mqtt The protocol obtains the temperature and humidity in real time ,mqtt It was built by Alibaba cloud itself `
All the libraries mentioned in this article can be found , I won't offer , If you need to comment, add your own email
This article is in Ardunio1.84 Developed in the environment
dh11 The power supply is connected to 3.3v,data Pick up esp32 D2

#include "DHT.h"
#include <PubSubClient.h>
#include <WiFi.h>

#define WIFI_AP "**"//wifi name 
#define WIFI_PASSWORD "*******"//wifi password 

#define DHTPIN 2 // DH11 Pick up IO 2
#define DHTTYPE DHT11 // DHT 11
char MqttServer[] = "www.chenxiky.com";// Built mqtt Server domain name or ip The address can be 

//  Initializing the Ethernet client object  -- WiFiClient.h
WiFiClient espClient;

//  initialization DHT11 sensor 
DHT dht(DHTPIN, DHTTYPE);

//  initialization MQTT library PubSubClient.h The object of 
PubSubClient client(espClient);

int status = WL_IDLE_STATUS;
unsigned long lastSend;



void setup() {
    
  Serial.begin(9600);
  Serial.println(" Temperature and humidity data :");
  dht.begin();

  InitWiFi();                                //  Connect WiFi
  client.setServer( MqttServer, 1883 );      //  Connect WiFi after , Connect MQTT The server 
  lastSend = 0;
}

void loop() {
    
  
 status = WiFi.status();
  if ( status != WL_CONNECTED) {
    
    while ( status != WL_CONNECTED) {
    
      Serial.print("[loop()]Attempting to connect to WPA SSID: ");
      Serial.println(WIFI_AP);
      //  Connect WiFi hotspot 
      status = WiFi.begin(WIFI_AP, WIFI_PASSWORD);
      delay(1000);
    }
    Serial.println("[loop()]Connected to AP");
  }

  if ( !client.connected() ) {
    
    reconnect();
  }

  if ( millis() - lastSend > 1000 ) {
     //  For timing 1 Send data once per second 
    getAndSendTemperatureAndHumidityData(); //  Get the temperature and humidity data and send it to MQTT Go to the server 
    lastSend = millis();
  }

  client.loop();
}

/* * *  Read temperature and humidity data , Then send it to MQTT Go to the server  * */
void getAndSendTemperatureAndHumidityData()
{
    
  Serial.println("Collecting temperature data.");

  //  Probably 1s Read once 
  delay(1000);
  float h = dht.readHumidity();
  float t = dht.readTemperature();

  //  Check whether the temperature and humidity failed to be read 
  if (isnan(h) || isnan(t)) {
    
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  Serial.print("Humidity: ");
  Serial.print(h);
  Serial.print(" %\t");
  Serial.print("Temperature: ");
  Serial.print(t);
  Serial.print(" *C ");

  String temperature = String(t);
  String humidity = String(h);

  // Just debug messages
  Serial.print( "Sending temperature and humidity : [" );
  Serial.print( temperature ); Serial.print( "," );
  Serial.print( humidity );
  Serial.print( "] -> " );

  //  Construct a  JSON  Format payload String 
  String payload = "{";
  payload += "\"temperature\":"; payload += temperature; payload += ",";
  payload += "\"humidity\":"; payload += humidity;
  payload += "}";

  // Send payload
  char attributes[100];
  payload.toCharArray( attributes, 100 );
  
  // boolean publish(const char* topic, const char* payload);
  
//wendu This is the topic of publication  , You can receive the temperature and humidity by subscribing to this topic 
  client.publish( "wendu", attributes );
  
  Serial.print("[publish]-->>");
  Serial.println( attributes );
}

void InitWiFi()
{
    
  delay(10);
  //  Try to connect WiFi The Internet 
  while ( status != WL_CONNECTED) {
    
    Serial.print("[InitWiFi]Attempting to connect to WPA SSID: ");
    Serial.println(WIFI_AP);
    // Connect to WPA/WPA2 network
    status = WiFi.begin(WIFI_AP, WIFI_PASSWORD);
    delay(1000);
  }
  Serial.println("[InitWiFi]Connected to AP");
}

/** * * MQTT Client disconnection reconnection function  * */

void reconnect() {
    
  //  Keep cycling until it is connected MQTT The server 
  while (!client.connected()) {
    
    Serial.print("[reconnect]Connecting to MQTT Server ...");
    //  Try to connect connect Is an overloaded function  (clientId, username, password)
    if ( client.connect("ESP_32", NULL, NULL) ) {
    
      Serial.println( "[DONE]" );
    } else {
    
      Serial.print( "[FAILED] [ mqtt connect error code = " );
      Serial.print( client.state() );
      Serial.println( " : retrying in 5 seconds]" );// Wait 5 seconds before retrying
      delay( 5000 );
    }
  }
}