Implementation of simple cubecap+fresnel shader in unity

Shader "Unlit/cubecap"
{
    //cubecap
    Properties{
        _NormalMap(" Normal map ", 2D) = "bump" {}
        _Cubemap(" Environment mapping ", Cube) = "_Skybox" {}
        _MidMapLevel(" Map blur ", Range(0, 7)) = 1.227742
        _fresnelpow(" Fresnel intensity ", Range(0, 1)) = 1
        _env("env", Range(0, 5)) = 1.93491
    }
        SubShader{
            Tags {
                "RenderType" = "Opaque"
            }
            Pass {
                Name "FORWARD"
                Tags {
                    "LightMode" = "ForwardBase"
                }

                CGPROGRAM
                #pragma vertex vert
                #pragma fragment frag
                #include "UnityCG.cginc"
                #pragma multi_compile_fwdbase_fullshadows
                #pragma target 3.0
            // Input parameters 
            uniform samplerCUBE _Cubemap;
            uniform sampler2D _NormalMap;
            uniform float _MidMapLevel;
            uniform float _fresnelpow;
            uniform float _env;
            // Input structure 
            struct VertexInput {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float4 tangent : TANGENT;
                float2 uv0 : TEXCOORD0;
            };
            // Output structure 
            struct VertexOutput {
                float4 pos : SV_POSITION;
                float2 uv0 : TEXCOORD0;
                float3 nDirWS : TEXCOORD1;
                float3 tDirWS : TEXCOORD2;
                float3 bDirWS : TEXCOORD3;
                float3 posWS : TEXCOORD4;
            };
            // The vertices shader
            VertexOutput vert(VertexInput v) {
                VertexOutput o = (VertexOutput)0;
                o.uv0 = v.uv0;
                o.nDirWS = UnityObjectToWorldNormal(v.normal);
                o.tDirWS = normalize(mul(unity_ObjectToWorld, float4(v.tangent.xyz, 0.0)).xyz);
                o.bDirWS = normalize(cross(o.nDirWS, o.tDirWS) * v.tangent.w);
                o.pos = UnityObjectToClipPos(v.vertex);
                o.posWS = mul(unity_ObjectToWorld,v.vertex);
                return o;
            }
            // Pixels shader
            float4 frag(VertexOutput i) : COLOR{
                // Vector preparation 
                float3  nDirTS = UnpackNormal(tex2D(_NormalMap, i.uv0)).rgb;
                float3x3 tbn = float3x3(i.tDirWS, i.bDirWS, i.nDirWS);
                float3 nDirWS = normalize(mul(nDirTS, tbn));
                float3 vDirWS = normalize(_WorldSpaceCameraPos.xyz - i.posWS.xyz);
                float3 vrDirWS = reflect(-vDirWS, nDirWS);

                // Intermediate quantity preparation 
                float ndotv = dot(nDirWS,vDirWS);

                // Illumination model 
                float3 cubemap = texCUBElod(_Cubemap,float4(vrDirWS, _MidMapLevel) );
                float fresnel = pow(1.0 - ndotv, _fresnelpow);
                float3 envSpcLighting = cubemap * fresnel * _env;

                // Return value 
                 return fixed4(envSpcLighting,1);
                  }
            ENDCG
            }
        }
   FallBack "Diffuse"
}

Effect of implementation ：