VBA upload pictures

The question comes from the post ：VBA How to pass winHttp、xmlHttp post Upload pictures Ask the boss for advice

There is no encryption in the whole process , Relatively simple , Don't do any analysis , Use Fiddler Grab the bag and check , It can be used quickly python Reappear

import requests
from io import BytesIO
from requests_toolbelt.multipart.encoder import MultipartEncoder

def main():
    file_name = '6da2ddc8124d0ba7045c38925eb857c0.jpeg'
    fields = {
    
        "image": (file_name, BytesIO(open(file_name, 'rb').read()), 'image/jpeg'),
        "fileId": file_name,
        "initialPreview": '[]',
        "initialPreviewConfig": '[]',
        "initialPreviewThumbTags": '[]'
    }
    multipart = MultipartEncoder(
        fields=fields,
        boundary='----WebKitFormBoundaryAx0QwuMECh2eIreV'
    )
    headers = {
    
        "X-Requested-With": "XMLHttpRequest",
        "Content-Type": multipart.content_type,
    }
    data = multipart.to_string()
    response = requests.post('https://www.imgtp.com/upload/upload.html', headers=headers, data=data)
    print(response.status_code)
    print(response.headers)
    print(response.request.headers)
    print(response.json())


if __name__ == '__main__':
    main()

Basically copy , Finally, you can get the online picture address . The difficulty lies in how to use VBA To upload .
1. Because there are no wheels , all multipart The packaging needs to be handled by yourself .
2. The request body contains binary files

One 、
To solve the first problem , Can be in vba Binary data generated in （ namely Byte Array ） And python Comparison of , Until the two data are exactly the same .

Two 、 Because we need to submit byte array , Then you have to use 【WinHttp.WinHttpRequest.5.1】 object .

The code of the submission part is as follows

Sub upload()
    Const Boundary As String = "----WebKitFormBoundaryAx0QwuMECh2eIreV"
    Const file_name As String = "6da2ddc8124d0ba7045c38925eb857c0.jpeg"
    Dim image_byte() As Byte
    Dim data() As Byte
    image_byte = openbytefile(ActiveWorkbook.path & "\" + file_name)
    Dim bytes As bytearray
    Set bytes = New bytearray
    
    bytes.update encodeutf8("--" & Boundary & vbNewLine)
    bytes.update encodeutf8("Content-Disposition: form-data; name=""image""; filename=""" & file_name & """" & vbNewLine)
    bytes.update encodeutf8("Content-Type: image/jpeg" & vbNewLine)
    bytes.update encodeutf8(vbNewLine)
    bytes.update image_byte
    bytes.update encodeutf8(vbNewLine)
    
    bytes.update encodeutf8("--" & Boundary & vbNewLine)
    bytes.update encodeutf8("Content-Disposition: form-data; name=""fileId""" & vbNewLine)
    bytes.update encodeutf8(vbNewLine & vbNewLine)
    bytes.update encodeutf8(file_name & vbNewLine)
    
    bytes.update encodeutf8("--" & Boundary & vbNewLine)
    bytes.update encodeutf8("Content-Disposition: form-data; name=""initialPreview""" & vbNewLine)
    bytes.update encodeutf8(vbNewLine & vbNewLine)
    bytes.update encodeutf8("[]" & vbNewLine)
    
    bytes.update encodeutf8("--" & Boundary & vbNewLine)
    bytes.update encodeutf8("Content-Disposition: form-data; name=""initialPreviewConfig""" & vbNewLine)
    bytes.update encodeutf8(vbNewLine & vbNewLine)
    bytes.update encodeutf8("[]" & vbNewLine)
    
    bytes.update encodeutf8("--" & Boundary & vbNewLine)
    bytes.update encodeutf8("Content-Disposition: form-data; name=""initialPreviewThumbTags""" & vbNewLine)
    bytes.update encodeutf8(vbNewLine & vbNewLine)
    bytes.update encodeutf8("[]" & vbNewLine)
    
    bytes.update encodeutf8("--" & Boundary & "--" & vbNewLine)
    
    data = bytes.digest
    
    Dim http As Object
    Set http = CreateObject("WinHttp.WinHttpRequest.5.1")
    Dim htmlurl As String
    htmlurl = "https://www.imgtp.com/upload/upload.html"
    Dim htmltext As String
    
    With http
        .Open "POST", htmlurl, False
        .SetRequestHeader "User-Agent", "python-requests/2.25.1"
        .SetRequestHeader "Accept-Encoding", "gzip, deflate"
        .SetRequestHeader "Accept", "*/*"
        .SetRequestHeader "Connection", "keep-alive"
        .SetRequestHeader "X-Requested-With", "XMLHttpRequest"
        .SetRequestHeader "Content-Type", "multipart/form-data; boundary=" & Boundary
        .SetRequestHeader "Content-Length", CStr(UBound(data) + 1)
        .Send data
        Dim body() As Byte
        body = .responseBody
        htmltext = encoding(body, "utf-8")
    End With
    
    Debug.Print htmltext
End Sub

Here I write a class myself , In order to facilitate the splicing of binary data

Option Explicit

Private data() As Byte


Public Sub Class_Initialize()
    ReDim data(0 To 0)
End Sub


Public Sub update(body() As Byte)
    ReDim Preserve data(0 To (UBound(data) - LBound(data) + UBound(body) - LBound(body) + 1))
    Dim i As Long
    For i = UBound(body) To 0 Step -1
        data(UBound(data) - i) = body(UBound(body) - i)
    Next i
End Sub


Public Property Get digest() As Byte()
    Dim temp() As Byte
    ReDim temp(0 To UBound(data) - 1)
    Dim i As Long
    For i = 1 To UBound(data) Step 1
        temp(i - 1) = data(i)
    Next i
    digest = temp
End Property


Public Sub Class_Terminate()
    ReDim data(0 To 0)
End Sub

More content can be added to my planet