Unity shader cartoon style rendering

Cartoon style rendering

The key to achieving

1. Render a more obvious outline
   Use two Pass
   first Pass： Render the whole back panel with contour , And in the perspective space , Expand the model vertices outward along the normal direction .
   

the second Pass： Normal rendering element

In order to avoid some concave models blocking the front panel after expansion , We take the normal z Component processing , Make it a negative value , In this way, it will not exceed the original part after expansion .

2. Add more obvious highlights
   Also need to calculate , Normals and h Dot product result of vector .
   We judge the result of dot multiplication , If it is greater than the threshold , Indicates that it is within the highlight range . If it is less than the threshold, it means it is not in the highlight range .
   
   In order to solve the problem of uneven transition at the edge of the highlight , We make use of smoothstep function , If the difference between the two is greater than a certain value , Then for 1, If it is less than a certain value, it is 0, If within a certain range , Then for [0,1] Number between , So when it is within a certain range of the boundary , Let's take the difference between the two colors , Make the transition smooth .
   
   Realization effect
   
   Code

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Custom/Chapter14-ToonShading"
{
    
    Properties
    {
    
        _Color ("Color Tint", Color) = (1,1,1,1)
        _MainTex ("Main Tex", 2D) = "white" {
    }
        // Diffuse gradient texture 
        _Ramp("Ramp Texture",2D)="white"{
    }
        // Marginal width 
        _Outline("Outline",Range(0,1))=0.1
        // Marginal color 
        _OutlineColor("Outline Color",Color)=(0,0,0,1)
        // The color of the highlight 
        _Specular("Specular",Color)=(1,1,1,1)
        // The threshold of highlight 
        _SpecularScale("Specular Scale",Range(0,0.1))=0.01
    }
    SubShader
    {
    
    // Render back 
    Pass{
    
    NAME "OUTLINE"

    // Eliminate the front 
    Cull Front
    CGPROGRAM
    #pragma vertex vert 
    #pragma fragment frag 
    #include "unityCG.cginc"

	float _Outline;
	fixed4 _OutlineColor;

    struct a2v{
    
    float4 vertex:POSITION;
    float3 normal:NORMAL;
    };

    struct v2f{
    
    float4 pos:SV_POSITION;
    };

    v2f vert(a2v v){
    
    v2f o;
    // Coordinate conversion to perspective space 
    float4 pos =mul(UNITY_MATRIX_MV,v.vertex);
    // Normal is converted to perspective coordinates 
    float3 normal =mul((float3x3)UNITY_MATRIX_MV,v.normal);

    // Vertex expansion 
    normal.z=-0.5;
    pos =pos+float4(normalize(normal),0)*_Outline;
    o.pos =mul(UNITY_MATRIX_P,pos);

    return o;
    }

    fixed4 frag(v2f i):SV_Target{
    
    return float4(_OutlineColor.rgb,1);
    }
    ENDCG
    }

    // Render front 
    Pass{
    
    Tags{
    "LightMode" = "ForwardBase"}

    Cull Back
    CGPROGRAM
    #pragma vertex vert 
    #pragma fragment frag 
    #pragma multi_compile_fwdbase

    #include "UnityCG.cginc"
	#include "Lighting.cginc"
	#include "AutoLight.cginc"
	#include "UnityShaderVariables.cginc"

    fixed4 _Color;
	sampler2D _MainTex;
	float4 _MainTex_ST;
	sampler2D _Ramp;
	fixed4 _Specular;
	fixed _SpecularScale;

    struct a2v{
    
    float4 vertex:POSITION;
    float3 normal:NORMAL;
    float2 texcoord:TEXCOORD0;
    };
    struct v2f{
    
    float4 pos:SV_POSITION;
    float3 worldNormal:TEXCOORD0;
    float3 worldPos:TEXCOORD1;
    float2 uv:TEXCOORD2;
    SHADOW_COORDS(3)
    };

    v2f vert(a2v v){
    
    v2f o;
    o.pos =UnityObjectToClipPos(v.vertex);
    o.uv=TRANSFORM_TEX(v.texcoord,_MainTex);
    o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);
    o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;

    TRANSFER_SHADOW(o);
    return o;
    }

    fixed4 frag(v2f i):SV_Target{
    
    // Calculate the various variables needed 
    	fixed3 worldNormal = normalize(i.worldNormal);
		fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
		fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
		fixed3 worldHalfDir = normalize(worldLightDir + worldViewDir);
				
        // Sample the color 
		fixed4 c = tex2D (_MainTex, i.uv);
        // Anti chromaticity 
		fixed3 albedo = c.rgb * _Color.rgb;
				
        // Ambient light 
		fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
		// shadow 
		UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
		// Half Lambert diffuse reflection coefficient 
		fixed diff =  dot(worldNormal, worldLightDir);
        // Diffuse reflectance coefficient 
		diff = (diff * 0.5 + 0.5) * atten;
		
        // Diffuse light 
		fixed3 diffuse = _LightColor0.rgb * albedo * tex2D(_Ramp, float2(diff, diff)).rgb;
		
        // highlights 
		fixed spec = dot(worldNormal, worldHalfDir);
        // Very small w
		fixed w = fwidth(spec) * 2.0;
        // stay 0-1 Difference between ,step(0.0001, _SpecularScale) Guarantee _SpecularScale by 0 The highlight color is 0
		fixed3 specular = _Specular.rgb * lerp(0, 1, smoothstep(-w, w, spec + _SpecularScale - 1)) * step(0.0001, _SpecularScale);
				
        // Global illumination plus diffuse reflection plus highlights 
		return fixed4(ambient + diffuse + specular, 1.0);
    }
    ENDCG
    }
    }
    FallBack "Diffuse"
}