Simulating Sir disease transmission model with netlogo

Studying recently Netlogo Software , Its language is very different from the programming language I learned before . After reading the code of the model library, I slowly understand . Here are SIR Propagation model code .

Need to create
Button ：setup, go
slider ：num-nodes, initial-outbreak-size, infect-rate, recover-rate


(’;’ It's a comment )

;SIR Propagation model 

turtles-own
[
  infected?		;  The value is  true  perhaps  false
  recover?
  explore?
]

globals[	;  Global variables 
  average-node-degree	;  Node average degree 
]

;;;;;;;;;;;;;;;;;;;;;;;;
;;; Setup Procedures ;;;
;;;;;;;;;;;;;;;;;;;;;;;;

to setup		; setup Button method 
  clear-all
  set average-node-degree 4		;  Set average to 4
  setup-nodes
  setup-spatially-clustered-network
  ask n-of initial-outbreak-size turtles		;  From all turtles Select the initial-outbreak-size individual （ Initial infection node ）
    [ become-infected ]
  ask links [ set color white ]
  reset-ticks
end

to setup-nodes		;  Initialize node 
  set-default-shape turtles "circle"
  create-turtles num-nodes[
    setxy (random-xcor * 0.95) (random-ycor * 0.95)
    become-susceptible
    set size 2
    initial-explored
  ]
end

to setup-spatially-clustered-network		;  Initialize edge connection 
    let num-links (average-node-degree * num-nodes) / 2
  while [count links < num-links ]
  [
    ask one-of turtles             ;;  The drawn edges have a layout 
    [
      let choice (min-one-of (other turtles with [not link-neighbor? myself])
                   [distance myself])
      if choice != nobody [ create-link-with choice ]
    ]
  ]
  ; make the network look a little prettier
  repeat 10
  [
    layout-spring turtles links 0.1 (world-width / (sqrt num-nodes)) 1
  ]
end

;;;;;;;;;;;;;;;;;;;;;;;;
;;; go Procedures ;;;
;;;;;;;;;;;;;;;;;;;;;;;;

to go
  if all? turtles [not infected?]
    [ stop ]
  if all? turtles [recover?]
    [ stop ]
  spread-virus
  recover-virus
  tick
end

to spread-virus
  ask turtles [ initial-explored ]  ;;explore Value initialization , All for false.true Indicates the infected nodes in this round 
  ask turtles with [infected?]
  [
    ask link-neighbors with [not recover?]
    [
      if random-float 1 < infect-rate
      [ 
        become-infected 
        change-explore
      ]
    ]
  ]
end

to recover-virus
  ask turtles with [infected? and not explore?]
  [
    if random-float 1 < recover-rate
    [
      become-recovery
    ]
  ]
end


to initial-explored
  set explore? false
end

to change-explore
  set explore? true
end

to become-susceptible
  set infected? false
  set recover? false
  set color blue
end

to become-infected
  set infected? true
  set recover? false
  set color red
end

to become-recovery
  set infected? false
  set recover? true
  set color yellow
end