D multi production single consumption

original text

import std.stdio;
import std.concurrency;
import std.algorithm;
import std.range;
import std.exception;
import std.format;
import core.thread;

struct Progress {
    
  Tid tid;          //  Identity of the reporting thread 
  size_t amount;    //  speed of progress 
  size_t total;     //  Overall progress 
}

void display(Progress[Tid] progresses) {
    
  const amount = progresses.byValue.map!(p => p.amount).sum;
  const total = progresses.byValue.map!(p => p.total).sum;
  writefln!"%6.2f%%"(100.0 * amount / total);
}

//  The worker thread 
void download(string url) {
    
  writefln!"%s Thread downloaded %s."(thisTid, url);
  enum total = 20;
  foreach (i; 0 .. total) {
    
    //  Simulate progress 
    Thread.sleep(100.msecs);

    //  Report progress to owner 
    ownerTid.send(Progress(thisTid, i + 1, total));
  }
}

void main() {
    
  auto list = [ "dlang.org", "ddili.org" ];
  auto downloaders = list.length.iota
                     .map!(i => spawnLinked(&download, list[i])).array;

  Progress[Tid] progresses;
  size_t finished = 0;

  while (finished != list.length) {
    
    receive(
      (LinkTerminated arg) {
    
        ++finished;

        //  Exit or not 
        enforce((arg.tid in progresses) &&
                (progresses[arg.tid].amount ==  progresses[arg.tid].total),
                format!"%s The thread exited unexpectedly "(arg.tid));
      },

      (Progress progress) {
    
        progresses[progress.tid] = progress;
        progresses.display();
      }
    );
  }

  writeln(" Handling download files ");
}