原文發布在 https://github.com/33357/smartcontract-apps這是一個面向中文社區，分析市面上智能合約應用的架構與實現的倉庫。歡迎關注開源知識項目！

Compound RateModel合約解析

RateModel合約是用來計算 Compound 上特定代幣借貸利率的合約，分析它可以知道借貸利率的計算方法。

演示代碼倉庫：https://github.com/33357/compound-protocol

WhitePaperInterestRateModel.sol

直線型利率模型

合約初始化

• 公共函數（合約內外部都可以調用）
  • constructor
    • 代碼速覽

      constructor(uint baseRatePerYear, uint multiplierPerYear) public {
                
          baseRatePerBlock = baseRatePerYear.div(blocksPerYear);
          multiplierPerBlock = multiplierPerYear.div(blocksPerYear);
          emit NewInterestParams(baseRatePerBlock, multiplierPerBlock);
      }
      

    • 參數分析
      函數 constructor 的入參有 2 個，出參有 0 個，對應的解釋如下：

      constructor(
          uint baseRatePerYear, // 年基准利率
          uint multiplierPerYear // 年利率乘數
      ) public {
                
          ...
      }
      

    • 實現分析

      ...
      {
                
          // 塊基准利率 = 年基准利率 / 年塊數
          baseRatePerBlock = baseRatePerYear.div(blocksPerYear);
          // 塊利率乘數 = 年利率乘數 / 年塊數
          multiplierPerBlock = multiplierPerYear.div(blocksPerYear);
          // 觸發事件 NewInterestParams
          emit NewInterestParams(baseRatePerBlock, multiplierPerBlock);
      }
      

    • 總結
      合約需要按 block 作為時間單比特來計算利率，因此需要將 baseRatePerYear 和 multiplierPerYear 轉換為 baseRatePerBlock 和 multiplierPerBlock。這裏的 blocksPerYear 為 2102400，是按照平均 15秒 一個 block 計算的。

資金借出率

• 公共函數（合約內外部都可以調用）
  • utilizationRate
    • 代碼速覽

      function utilizationRate(uint cash, uint borrows, uint reserves) public pure returns (uint) {
                
          if (borrows == 0) {
                
              return 0;
          }
          return borrows.mul(1e18).div(cash.add(borrows).sub(reserves));
      }
      

    • 參數分析
      函數 utilizationRate 的入參有 3 個，出參有 1 個，對應的解釋如下：

      constructor(
          uint cash, // 代幣餘額
          uint borrows, // 用戶借出代幣總數
          uint reserves // 儲備代幣總數
      ) public view returns (
          uint // 資金借出率
      ){
                
          ...
      }
      

    • 實現分析

      ...
      {
                
          // 如果借出代幣總數為 0，資金借出率也為 0
          if (borrows == 0) {
                
              return 0;
          }
          // borrows * 1e18 / (cash + borrows - reserves)
          return borrows.mul(1e18).div(cash.add(borrows).sub(reserves));
      }
      

    • 總結
      utilizationRate 用於計算代幣的 資金借出率，資金借出率 的計算公式為 資金借出率 = 借出代幣總數 / (代幣餘額 + 借出代幣總數 - 儲備代幣總數)。由於使用無符號整數計算 資金借出率 會精度不够，所以需要乘以 1e18，擴大精度範圍。

資金利率

• 公共函數（合約內外部都可以調用）
  • getBorrowRate
    • 代碼速覽

      function getBorrowRate(uint cash, uint borrows, uint reserves) public view returns (uint) {
                
          uint ur = utilizationRate(cash, borrows, reserves);
          return ur.mul(multiplierPerBlock).div(1e18).add(baseRatePerBlock);
      }
      

    • 參數分析
      函數 getBorrowRate 的入參有 3 個，出參有 1 個，對應的解釋如下：

      function getBorrowRate(
          uint cash, // 代幣餘額
          uint borrows, // 用戶借出代幣總數
          uint reserves // 儲備代幣總數
      ) public view returns (
          uint // 塊借出利率
      ) {
                
          ...
      }
      

    • 實現分析

      ...
      {
                
          // 計算資金借出率
          uint ur = utilizationRate(cash, borrows, reserves);
          // ur * multiplierPerBlock / 1e18 + baseRatePerBlock
          return ur.mul(multiplierPerBlock).div(1e18).add(baseRatePerBlock);
      }
      

    • 總結
      getBorrowRate 用於計算代幣的 塊借出利率，塊借出利率 的計算公式為 塊借出利率 = 資金借出率 * 塊利率乘數 + 塊基准利率。由於 資金借出率 擴大了精度範圍，需要除以 1e18 得到實際值。
  • getSupplyRate
    • 代碼速覽

      function getSupplyRate(uint cash, uint borrows, uint reserves, uint reserveFactorMantissa) public view returns (uint) {
                
          uint oneMinusReserveFactor = uint(1e18).sub(reserveFactorMantissa);
          uint borrowRate = getBorrowRate(cash, borrows, reserves);
          uint rateToPool = borrowRate.mul(oneMinusReserveFactor).div(1e18);
          return utilizationRate(cash, borrows, reserves).mul(rateToPool).div(1e18);
      }
      

    • 參數分析
      函數 getSupplyRate 的入參有 4 個，出參有 1 個，對應的解釋如下：

      getSupplyRate(
          uint cash, // 代幣餘額
          uint borrows, // 用戶借出代幣總數
          uint reserves, // 儲備代幣總數
          uint reserveFactorMantissa // 儲備金率
      ) public view returns (
          uint // 塊質押利率
      ) {
                
          ...
      }
      

    • 實現分析

      ...
      {
                
          // 1 - reserveFactorMantissa
          uint oneMinusReserveFactor = uint(1e18).sub(reserveFactorMantissa);
          // 獲取借款利率 borrowRate
          uint borrowRate = getBorrowRate(cash, borrows, reserves);
          // borrowRate * (1 - reserveFactorMantissa)
          uint rateToPool = borrowRate.mul(oneMinusReserveFactor).div(1e18);
          // utilizationRate * borrowRate * (1 - reserveFactorMantissa)
          return utilizationRate(cash, borrows, reserves).mul(rateToPool).div(1e18);
      }
      

    • 總結
      getSupplyRate 用於計算代幣的 塊質押利率，塊質押利率 的計算公式為 塊質押利率 = 資金借出率 * 借款利率 * (1 - 儲備金率) = 借款利率 * 資金借出率 * (1 - 儲備金率)。由於 資金借出率 擴大了精度範圍，需要除以 1e18 得到實際值。

BaseJumpRateModelV2.sol

拐點型利率模型

合約初始化

• 內部函數（僅合約內可以調用）
  • constructor
    • 代碼速覽

      constructor(uint baseRatePerYear, uint multiplierPerYear, uint jumpMultiplierPerYear, uint kink_, address owner_) internal {
                
          owner = owner_;
          updateJumpRateModelInternal(baseRatePerYear,  multiplierPerYear, jumpMultiplierPerYear, kink_);
      }
      

    • 參數分析
      函數 constructor 的入參有 5 個，出參有 0 個，對應的解釋如下：

      constructor(
          uint baseRatePerYear, // 年基准利率
          uint multiplierPerYear // 年利率乘數
          uint jumpMultiplierPerYear, // 拐點年利率乘數
          uint kink_, // 拐點資金借出率
          address owner_ // 所有者
      ) internal {
                
          ...
      }
      

    • 實現分析

      ...
      {
                
          // 記錄所有者
          owner = owner_;
          // 更新拐點利率模型參數
          updateJumpRateModelInternal(baseRatePerYear,  multiplierPerYear, jumpMultiplierPerYear, kink_);
      }
      

    • 總結
      拐點型利率模型 比 直線型利率模型 多了 拐點年利率乘數 和 拐點資金借出率 這兩個參數。
  • updateJumpRateModelInternal
    • 代碼速覽

      function updateJumpRateModelInternal(uint baseRatePerYear, uint multiplierPerYear, uint jumpMultiplierPerYear, uint kink_) internal {
                
          baseRatePerBlock = baseRatePerYear.div(blocksPerYear);
          multiplierPerBlock = (multiplierPerYear.mul(1e18)).div(blocksPerYear.mul(kink_));
          jumpMultiplierPerBlock = jumpMultiplierPerYear.div(blocksPerYear);
          kink = kink_;
          emit NewInterestParams(baseRatePerBlock, multiplierPerBlock, jumpMultiplierPerBlock, kink);
      }
      

    • 參數分析
      函數 updateJumpRateModelInternal 的入參有 4 個，出參有 0 個，對應的解釋如下：

      function updateJumpRateModelInternal(
          uint baseRatePerYear, // 年基准利率
          uint multiplierPerYear // 年利率乘數
          uint jumpMultiplierPerYear, // 拐點年利率乘數
          uint kink_, // 拐點資金借出率
      ) internal {
                
          ...
      }
      

    • 實現分析

      ...
      {
                
          // 塊基准利率 = 年基准利率 / 年塊數
          baseRatePerBlock = baseRatePerYear.div(blocksPerYear);
          // 塊利率乘數 = 年基准利率 / (年塊數 * 拐點資金借出率)
          multiplierPerBlock = (multiplierPerYear.mul(1e18)).div(blocksPerYear.mul(kink_));
          // 拐點塊利率乘數 = 拐點年利率乘數 / 年塊數
          jumpMultiplierPerBlock = jumpMultiplierPerYear.div(blocksPerYear);
          // 記錄拐點資金借出率
          kink = kink_;
          // 觸發事件 NewInterestParams
          emit NewInterestParams(baseRatePerBlock, multiplierPerBlock, jumpMultiplierPerBlock, kink);
      }
      

    • 總結
      拐點型利率模型 中計算 塊利率乘數 時，方法和 直線型利率模型 不一樣：拐點資金借出率 越高，塊利率乘數 越低，其目的我不是很清楚。(可能是拐點資金借出率越高的代幣市場深度越好，塊利率乘數可以設置的更低，大家可以討論一下)

資金借出率

• 公共函數（合約內外部都可以調用）
  • utilizationRate
    • 代碼速覽

      function utilizationRate(uint cash, uint borrows, uint reserves) public pure returns (uint) {
                
          if (borrows == 0) {
                
              return 0;
          }
          return borrows.mul(1e18).div(cash.add(borrows).sub(reserves));
      }
      

    • 參數分析
      函數 utilizationRate 的入參有 3 個，出參有 1 個，對應的解釋如下：

      constructor(
          uint cash, // 代幣餘額
          uint borrows, // 用戶借出代幣總數
          uint reserves // 儲備代幣總數
      ) public view returns (
          uint // 資金借出率
      ){
                
          ...
      }
      

    • 實現分析

      ...
      {
                
          // 如果借出代幣總數為 0，資金借出率也為 0
          if (borrows == 0) {
                
              return 0;
          }
          // 資金借出率 = borrows * 1e18 / (cash + borrows - reserves)
          return borrows.mul(1e18).div(cash.add(borrows).sub(reserves));
      }
      

    • 總結
      拐點型利率模型 中計算 資金借出率 和 直線型利率模型 相同。

資金利率

• 內部函數（僅合約內部可以調用）
  • getBorrowRate
    • 代碼速覽

      function getBorrowRateInternal(uint cash, uint borrows, uint reserves) internal view returns (uint) {
                
          uint util = utilizationRate(cash, borrows, reserves);
          if (util <= kink) {
                
              return util.mul(multiplierPerBlock).div(1e18).add(baseRatePerBlock);
          } else {
                
              uint normalRate = kink.mul(multiplierPerBlock).div(1e18).add(baseRatePerBlock);
              uint excessUtil = util.sub(kink);
              return excessUtil.mul(jumpMultiplierPerBlock).div(1e18).add(normalRate);
          }
      }
      

    • 參數分析
      函數 getBorrowRateInternal 的入參有 3 個，出參有 1 個，對應的解釋如下：

      function getBorrowRate(
          uint cash, // 代幣餘額
          uint borrows, // 用戶借出代幣總數
          uint reserves // 儲備代幣總數
      ) internal view returns (
          uint // 塊借出利率
      ) {
                
          ...
      }
      

    • 實現分析

      {
                
          // 獲取資金借出率 util
          uint util = utilizationRate(cash, borrows, reserves);
          // 如果 util < kink
          if (util <= kink) {
                
              // return util * multiplierPerBlock + baseRatePerBlock
              return util.mul(multiplierPerBlock).div(1e18).add(baseRatePerBlock);
          } else {
                
              // 拐點前塊借出利率 = kink * multiplierPerBlock + baseRatePerBlock
              uint normalRate = kink.mul(multiplierPerBlock).div(1e18).add(baseRatePerBlock);
              // 超出拐點資金借出率 = util - kink
              uint excessUtil = util.sub(kink);
              // 塊借出利率 = (util - kink) * jumpMultiplierPerBlock + kink * multiplierPerBlock + baseRatePerBlock
              return excessUtil.mul(jumpMultiplierPerBlock).div(1e18).add(normalRate);
          }
      }
      

    • 總結
      拐點型利率模型 中計算 塊借出利率 的計算公式分為兩部份：在 資金借出率 低於 拐點資金借出率 時，計算公式為：塊借出利率 = 資金借出率 * 塊利率乘數 + 塊基准利率；在 資金借出率 高於 拐點資金借出率 時，計算公式為：塊借出利率 = (資金借出率 - 拐點資金借出率) * 拐點塊利率乘數 + 拐點資金借出率 * 塊利率乘數 + 塊基准利率。
  • getSupplyRate
    • 代碼速覽

      function getSupplyRate(uint cash, uint borrows, uint reserves, uint reserveFactorMantissa) public view returns (uint) {
                
          uint oneMinusReserveFactor = uint(1e18).sub(reserveFactorMantissa);
          uint borrowRate = getBorrowRateInternal(cash, borrows, reserves);
          uint rateToPool = borrowRate.mul(oneMinusReserveFactor).div(1e18);
          return utilizationRate(cash, borrows, reserves).mul(rateToPool).div(1e18);
      }
      

    • 參數分析
      函數 getSupplyRate 的入參有 4 個，出參有 1 個，對應的解釋如下：

      getSupplyRate(
          uint cash, // 代幣餘額
          uint borrows, // 用戶借出代幣總數
          uint reserves, // 儲備代幣總數
          uint reserveFactorMantissa // 儲備金率
      ) public view returns (
          uint // 塊質押利率
      ) {
                
          ...
      }
      

    • 實現分析

      ...
      {
                
          // 1 - reserveFactorMantissa
          uint oneMinusReserveFactor = uint(1e18).sub(reserveFactorMantissa);
          // 獲取借款利率 borrowRate
          uint borrowRate = getBorrowRateInternal(cash, borrows, reserves);
          // rateToPool = borrowRate * (1 - reserveFactorMantissa)
          uint rateToPool = borrowRate.mul(oneMinusReserveFactor).div(1e18);
          // 塊質押利率 = utilizationRate * borrowRate * (1 - reserveFactorMantissa)
          return utilizationRate(cash, borrows, reserves).mul(rateToPool).div(1e18);
      }
      

    • 總結
      拐點型利率模型 中計算 資金質押利率 和 直線型利率模型 相同。