汇编课后作业

原文链接 —— SevenOne’Blog

作业1：字母转换

需求

1. 提示输入 # 号结束程序。
2. 提示输入一个字符。
3. 判断字符是否合法（a～z A～Z）
   • 合法输入：提示转换结果：输入转换结果。
   • 非法输入：计数，超过三次结束程序。
4. 输入 # 号结束程序。

流程图

代码实现

data segment
    count db 33h
    input db "Input $"
    program db " end of the program$"
    prompt db "Please enter a character: $"
    message db "Please enter the correct characters $"
    result db "The results: $"
data ends
code segment
    assume cs:code,ds:data
    main:
        mov ax,data
        mov ds,ax

        mov dx,offset input
        call ah09
        mov dl,23h
        call ah02
        mov dx,offset program
        call ah09
        call br
        jmp start

    start:  ;开始
        mov dx,offset prompt
        call ah09
        mov ah,01h
        int 21h
        call br
        cmp al,23h
        jz edit
        cmp al,5bh
        jl upper
        cmp al,60h
        jg lower

    upper:  ;处理大写
        cmp al,41h
        jl error
        add al,20h
        jmp print
    
    lower:  ;处理小写
        cmp al,7ah
        jg error
        sub al,20h
        jmp print

    print:  ;输出
        mov dx,offset result
        call ah09
        mov dl,al
        call ah02
        call br
        jmp start
    
    error:  ;错误处理
        dec count
        cmp count,30h
        jz edit
        mov dx,offset message
        call ah09
        call br
        jmp start

    edit:
        mov ah,4ch
        int 21h

    ah09 proc near
        push ax
        mov ah,09h
        int 21h
        pop ax
        ret
    ah09 endp

    ah02 proc near
        push ax
        mov ah,02h
        int 21h
        pop ax
        ret
    ah02 endp

    br proc near
        push dx
        mov dl,0ah
        call ah02
        pop dx
        ret
    br endp
code ends
    end main

作业2：计时器效果

需求

1. 00 ～ 99 循环显示。
2. 每个一段时间打印一个数字。
3. 打印当前数字前清除上一次输出的数字。
4. 按任意键退出程序

流程图

代码实现

data segment
    ten db 30h
    bis db 30h
data ends

code segment
    assume cs:code,ds:data
    start:
        mov ax,data
        mov ds,ax
    
    fbis:
        mov ah,0bh
        int 21h
        cmp al,00h
        jnz exit

        mov dl,ten
        call d02
        mov dl,bis
        call d02
        call timer
        mov dl,0dh
        call d02

        inc bis
        cmp bis,3ah
        jb fbis

        inc ten
        mov bis,30h
        cmp ten,3ah
        jb fbis

        mov ten,30h
        mov bis,30h
        jmp fbis
    
    exit:
        mov ah,4ch
        int 21h

    d02 proc near
        mov ah,02h
        int 21h
        ret
    d02 endp

    timer proc near
        push cx
        push dx
        mov cx,1000h
        fori:
            mov dx,50h
            forj:
                dec dx
                cmp dx,0h
                jg forj
            dec cx
            cmp cx,0h
            jg fori
        pop dx
        pop cx
        ret
    timer endp
code ends
    end start

作业3：模拟进制转换

需求

1. 将需要转换的值放到 BL 寄存器中（高阶版本：从键盘输入）
2. 输出 BL 中存放数据的二进制和十六进制。

流程图

代码

code segment
    assume cs:code
    start:
        mov bl,0a1h
        call toBinary
        call toHexade
    edit:
        mov ah,4ch
        int 21h

    toBinary proc near
        push bx
        push cx
        push dx
            mov cx,8
            loopi:
                rol bl,1
                mov dl,bl
                and dl,01h
                add dl,30h
                call d02
            loop loopi
            mov dl,'B'
            call d02
            call br
        pop dx
        pop cx
        pop bx
        ret
    toBinary endp

    toHexade proc near
        push bx
        push cx
        push dx
            mov cx,2
            loopj:
                push cx
                    mov cl,4
                    rol bl,cl
                pop cx
                mov dl,bl
                and dl,0fh
                cmp dl,09h
                jg letter
                jng number

                letter:
                    add dl,37h
                    jmp print
                
                number:
                    add dl,30h

                print:
                    call d02
            loop loopj
            mov dl,'H'
            call d02
        pop dx
        pop cx
        pop bx
        ret
    toHexade endp

    d02 proc near
        mov ah,02h
        int 21h
        ret
    d02 endp

    br proc near
        push dx
            mov dl,0ah
            call d02
        pop dx
        ret
    br endp
code ends
    end start